Xcopy - DOS/コマンドプロンプト コマンド一覧

使い方

XcopyはCopyコマンドと同様にファイルをコピーする機能を持ちますが、複数ファイルのコピーやディレクトリの一括コピーができるなど、Copyコマンドよりも高機能となっています。使い方としては、

xcopy /S /E C:\Foo N:\Bar\

のように、オプションを指定しつつ「コピー元」「コピー先」を指定することでコピーを行います(オプションは後ろに付けても問題ありません)。

Xcopyの特徴の1つに、Copyコマンドに比べてコピー操作を制御するオプションが豊富にあるという点があります。代表的なオプションに

• /Y : 強制的に上書きを行う
• /S : サブディレクトリもコピーする(空のディレクトリはコピーしない)
• /E : 空のディレクトリも含めてサブディレクトリもコピーする(「/S /E」としても可)
• /Q : コピー時の画面出力を省略する

といったものがあります。使い方の例は「例」もご覧ください。

構文

xcopy[.exe] <source> [<destination>] [/A | /M] [/D[:<date>]] [/P]
  [/S] [/E] [/V] [/W] [/Y] [/-Y] [/C] [/I] [/Q] [/F] [/L] [/H] [/R]
  [/T] [/U] [/K] [/N] [/G] [/O] [/X] [/Z] [/B] [/J]
  [/EXCLUDE:<file1>[+<file2>]...]
  [/COMPRESS] [/SPARSE]

解説

ファイルやディレクトリをコピーするプログラムで、Copyコマンドよりも詳細な指定を行うことができます。またCopyと異なり、ファイルをディレクトリごとコピーすることもできます。

[MS-DOS] Xcopyでは0バイトのファイルもコピーすることができます(Copyではコピーできません)。

[Windows XP？以降] ファイル属性やタイムスタンプによるファイル選択やコピー元とコピー先のミラーリングなどを行う場合は、Robocopyの使用も検討してください。

例

サンプル1

xcopy /Y C:\Documents\hoge.txt D:\Backup\

ファイル「C:\Documents\hoge.txt」を、ディレクトリ「D:\Backup」の中にコピーします。「/Y」オプションにより、既にファイルが存在する場合は無条件で(強制的に)上書きを行います。

サンプル2

xcopy /Y /Q /S /E E:\My\Directory\*.* F:\Foo\Bar\Directory\

ディレクトリ「E:\My\Directory」とその中身(ファイルおよびサブディレクトリ)を、ディレクトリ「F:\Foo\Bar\Directory」内にまるごとコピーします。「/S /E」があるため、ディレクトリ構造も含めてコピーされます。(/Y オプションがあるので中に含まれるファイルが一部存在する場合は無条件で上書きを行います。) また、「/Q」オプションによりコピー時にファイル名を画面に出力しません。

※ なお、「F:\Foo\Bar\Directory」が存在しない場合は自動的に作成されます。

サンプル3

xcopy /A /S /E /Y C:\MyDoc\*.* D:\Backup\MyDoc\

「C:\MyDoc」内にあるすべてのファイルのうち「アーカイブ属性」がついたファイルを、「D:\Backup\MyDoc」ディレクトリ内にコピーします。この際、「C:\MyDoc」内のサブディレクトリ内にあるファイルも(同じディレクトリ構造で)コピーします。

※ Attribコマンドの例もご覧ください。

サンプル4

xcopy /Y /Q /S /E /M E:\My\Directory\*.* F:\Foo\Bar\

ディレクトリ「E:\My\Directory」の中身のうち「アーカイブ属性」の付いたファイルおよびサブディレクトリを、ディレクトリ「F:\Foo\Bar」内にまるごとコピーします(中に含まれるファイルが一部存在する場合は無条件で上書きを行います)。「/M」オプションがあるため、コピー元ファイルについていたアーカイブ属性は解除されます。

サンプル5

echo F| xcopy /M file1.txt file2.txt

file1.txt に「アーカイブ属性」が付いている場合、file1.txt をコピーして file2.txt を作成します。「file2.txt」は末尾が「\」で終わっていないため、「file2.txt は受け側のファイル名ですか、ディレクトリ名ですか(F=ファイル、D=ディレクトリ)?」などの入力待ちが表示されますが、自動的に「F」を入力させるためにEchoコマンドを使用しています。

なお、コマンド実行後は file1.txt のアーカイブ属性は解除されます(file2.txt のアーカイブ属性は残ります)。

※ 単体のファイルをコピーする場合は通常Copyコマンドを使用します。
※ 「echo F」ではなく「echo D」とすると、「file2.txt」というディレクトリが作成され、その中に file1.txt がコピーされます。
※ file2.txtが存在する場合、「file2.txt は受け側のファイル名ですか、ディレクトリ名ですか(F=ファイル、D=ディレクトリ)?」ではなく「file2.txt を上書きしますか (Yes/No/All)?」といった入力待ちが表示される(のに対し与える入力が「F」のみとなる)ため、上記のコマンドは失敗します。強制的に上書きを行う場合は /Y スイッチを指定します。

サンプル6

xcopy /U /S /E /Y Z:\Data\*.* E:\Current\Data\

[Windows 95以降] 「Z:\Data」内のすべてのファイルを「E:\Current\Data」内にコピーしますが、コピーしようとするファイルがコピー先に存在し、コピー先のファイルが新しい場合はコピーしません。ファイルを更新するときなどに使います。

サンプル7 (バッチファイル)

@echo off
setlocal enableextension
for /F "tokens=1,2,* delims=:" %%i in ("%TIME%") do set MYTIME=%%i%%j
set DIR_NAME=E:\Backup\src_%DATE:/=%_%MYTIME%
if not exist "%DIR_NAME%" md "%DIR_NAME%"
xcopy /S /E /Y /Q /EXCLUDE:"E:\Backup\excludes.txt" D:\Develop\src\*.* "%DIR_NAME%\"

[Windows NT系] [拡張構文] 「E:\Backup」内に日付と時刻が名前に入ったディレクトリを作成し、その中に、「D:\Develop\src」内にあるファイルのうち「E:\Backup\excludes.txt」に記述されたパターンに一致するファイルを除くすべてのファイルをコピーします。このような記述のバッチファイルを作ることで、その時点におけるバックアップを簡単に作成することができます。

なお、ファイル名に文字「/」や「:」は使用できないため、ForやSetを用いて日付や時刻からそれらの文字を取り除いています。

関連項目

• Copyコマンド - シンプルにファイルをコピーしたいときに使います。
• Robocopyコマンド - より複雑な条件でコピーしたいときに使います。
• Rmdir(Rd)コマンド - ディレクトリを削除したいときに使います。
• Deltreeコマンド - MS-DOSやWindows95/98/Meでディレクトリを削除したいときに使います。
• Attribコマンド - アーカイブ属性はAttribコマンドで確認・変更できます。
• ワイルドカード(* や ?) - Xcopyコマンドはワイルドカードを使用できます。