For - DOS/コマンドプロンプト コマンド一覧

構文

for %variable in (<pattern>) do <command-line>

for /D %variable in (<pattern>) do <command-line>

for /R [[<drive-letter>:]<path>] %variable in (<pattern>) do <command-line>

for /L %variable in (<start>,<step>,<end>) do <command-line>

for /F ["<options>"] %variable in (<pattern>) do <command-line>

バッチファイル内でForを使用する場合、「%%variable」のように「%」を2つ並べる必要があります。これは、1つだけだと環境変数の%と見なされて、その内容(または空白)に置き換えられてしまうからです。

※ Forに限らず、バッチファイル内でコマンドまたはプログラムに「%」文字そのものを渡したい場合は「%%」と記述します。「%」のページもご覧ください。

解説

for /f "usebackq tokens=1,2 delims=:" %A in ('C1:Flower^

C2:Bird^

C3:Wind^

C4:Moon') do echo The value for key '%A' is '%B'.

for /f "tokens=1,2 delims=?" %A in ('for /f "delims=" %X in ('for /f "delims=" %Y in ('dir /b'^^^) do @echo %~fY'^) do @echo %~X?%~zX') do @echo %~nxA, %B

例

サンプル1

for %d in (*.dll) do regsvr32.exe /u "%d"

現在のディレクトリにあるすべての DLL ファイルに対して regsvr32.exe を実行し、COM DLL の登録削除を行います。

サンプル2 (バッチファイル)

@echo off
for %%f in (*.*) do echo %%f

現在のディレクトリにあるすべてのファイル(ディレクトリおよび隠しファイル・システムファイルを除く)を画面に表示します。

サンプル3

for /L %n in (8,-3,1) do @echo %n

[Windows NT系] [拡張構文] 画面には「8」「5」「2」が出力されます。

サンプル4

for /L %n in (1,1,%NUMBER_OF_PROCESSORS%) do hoge.exe %n

[Windows NT系] [拡張構文] 使用できる(論理)プロセッサーの数だけ「hoge.exe」を実行し、引数に何番目かを指定します。(「NUMBER_OF_PROCESSORS」はOSが設定している環境変数です。)

サンプル5

for /F "tokens=1,2,*" %1 in ("This is a pen.") do @echo "%1" "%2" "%3"

[Windows NT系] [拡張構文] 「/F」によりテキストの解析を行います。「tokens」オプションを使うことで、「%1」の他に「%2」と「%3」(「*」の指定により「%1」と「%2」に入らなかった残り全部が入ります)の変数が用意されています。これを実行すると、画面には「"This" "is" "a pen."」が出力されます。

サンプル6

for /F "tokens=2,3 delims=/" %p in ("%DATE%") do @echo %p%q

[Windows NT系] [拡張構文] 日付のうち「月」と「日」をつなげて出力します(システムの設定が「yyyy/mm/dd」形式の場合)。

サンプル7

for /F "usebackq delims=" %t in ("D:\My Files\hoge.txt") do @foo.exe "%t"

[Windows NT系] [拡張構文] 「D:\My Files\hoge.txt」の各行の内容を引数として「foo.exe」を実行します。ファイル名にスペースが含まれているため、「usebackq」オプションを使っています。なお、「delims=」でオプションを終えているため、%t には1行のデータが丸々入ります。

サンプル8

for /F "delims=" %F in ('dir /A /B') do @echo %~fF

[Windows NT系] [拡張構文] 現在のディレクトリに存在するディレクトリとファイルすべてをフルパスで画面に出力します。Dirコマンドの「/A」スイッチによりディレクトリや隠しファイル・システムファイルも含めて列挙され、「/B」スイッチによってそれらがファイル名のみ1行に1つずつ出力されるため、Forの「%F」にはそれらのファイル名が入るようになります。なお、「%~fF」とすることで(%Fに入っていた)ファイル名がフルパスになります(「%」を参照)。

※ ディレクトリを除いて隠しファイル・システムファイルを含めたい場合は「dir /A:-D /B」と指定します。

サンプル9 (バッチファイル)

for /F "tokens=1,2 delims=," %%p in ('tasklist /FO CSV /NH') do (
    if /i "%%~p"=="explorer.exe" echo %%~q: %%~p
)

[Windows NT系] [拡張構文] 「tasklist /FO CSV /NH」の実行による出力(現在実行中のプロセス一覧をCSV形式で出力)を「,」で区切り、その中で1番目のトークン(この場合はプロセス名)が「explorer.exe」に一致するもののみ、1番目と2番目(この場合はプロセスID)のトークンを出力しています。なお、「%~p」とすることでダブルクオーテーション「" "」を取り除いています。

※ バッチファイルのため「%」を重ねています。

サンプル10

for /F "tokens=1,2 delims=?" %a in ('^(for /R %x in ^(*.cpp^) do echo %~tx?%x?^) ^| findstr /r "^200[0-4]" ^| sort') do @echo %b : %a

[Windows NT系] [拡張構文] 現在のディレクトリとそのサブディレクトリすべてにある「*.cpp」ファイルを検索し、その中で更新日時が2000年～2004年であるファイルを古い順にすべて表示します。目的の結果を得るために、For「/F」で指定するコマンドの中にForとパイプを用いています(正しく解釈させるために「^」文字も使用します)。

まず、最初のForにおける「in」以降の括弧内で以下のコマンドを実行しています。

(for /R %x in (*.cpp) do echo %~tx?%x?) | findstr /r "^200[0-4]" | sort

このコマンドにおけるForで、現在のディレクトリとそのサブディレクトリすべてにある「*.cpp」を検索、Echoコマンドでその更新日時(「%~tx」)とファイル名を「?」文字区切りで出力します。このForコマンドにおける出力例は以下の通りです。

2013/06/30?G:\My Sources\Project1\hello.cpp?
2004/02/29?G:\My Sources\ProjectArchive\Hoge1\file1.cpp?
2003/01/30?G:\My Sources\ProjectArchive\Hoge1\file2.cpp?
2012/10/05?G:\My Sources\Temp\temp.cpp?

※ Forによる出力結果全体を次のコマンドに渡すため、Forの外側に「( )」が必要です。

つづいて、Findstrコマンドで「2000, 2001, 2002, 2003, 2004」のいずれかで始まる文字列を抽出します(Findstrで使用可能な正規表現「^200[0-4]」を用いています)。その結果は以下の通りです。

2004/02/29?G:\My Sources\ProjectArchive\Hoge1\file1.cpp?
2003/01/30?G:\My Sources\ProjectArchive\Hoge1\file2.cpp?

そして、Sortコマンドで昇順に並び替えるので出力が以下の通り変わります。

2003/01/30?G:\My Sources\ProjectArchive\Hoge1\file2.cpp?
2004/02/29?G:\My Sources\ProjectArchive\Hoge1\file1.cpp?

以上の出力結果を、外側のFor「/F」スイッチに解釈させます。一連のコマンドの中にパイプや括弧が含まれるため、外側のForなどに解釈されないようにそれらの文字の前に「^」を付けて記述します。

外側のForを使って解析すると、最終的に以下の出力が得られます。

G:\My Sources\ProjectArchive\Hoge1\file2.cpp : 2003/01/30
G:\My Sources\ProjectArchive\Hoge1\file1.cpp : 2004/02/29

なお、外側のForでは(結果的に)「%b」に有効なファイル名が入るため、「%~nxb」とすればディレクトリ名を除いたファイル名、「%~zb」とすればそのファイルのサイズを得ることができます。

※ バッチファイルでForの中にForを記述する場合、内部のForで宣言する %変数 (この例の場合は「%x」)を「%%%%x」などと記述する必要はなく、従来のバッチファイルでの変数利用と同様の記法「%%x」で問題ありません。

サンプル11 (バッチファイル)

@echo off
setlocal enabledelayedexpansion
set TEMPLATE_FILE=D:\Data\Template\hoge.xml
set OUT_FILE=D:\MyData\bar.xml
set MY_VERSION=123

type NUL > "%OUT_FILE%"
for /F "usebackq delims=" %%t in ("%TEMPLATE_FILE%") do (
    set TEMP_LINE=%%t
    set TEMP_LINE=!TEMP_LINE:[version]=%MY_VERSION%!
    echo !TEMP_LINE!>> "%OUT_FILE%"
)

[Windows NT系] [拡張構文] テンプレートファイル「D:\Data\Template\hoge.xml」をベースにファイル「D:\MyData\bar.xml」を作成しますが、その際「D:\Data\Template\hoge.xml」に「[version]」という記述が含まれていた場合、それを「MY_VERSION」の変数の値(この場合は「123」)に置き換えます。8行目では一旦出力ファイルの中身を空にし、12行目で変換されたデータをファイルに追加出力しています。

なお、「[version]」文字列を置き換えるために行の内容を一旦仮の変数に設定し、「%」で使用できる拡張された展開方法を用いて文字列を置き換えたのち、その内容をファイルに出力していますが、Forのコマンドライン内で変数を作成・書き換えおよび使用するため、「!」による遅延環境変数展開機能を用いています(「!」を「%」にすると意図した動作が得られません)。

※ この例では「hoge.xml」はShift JISで記述されている必要があり、日本語文字が含まれたUTF-8形式などの場合「bar.xml」が文字化けする場合があります。UTF-8形式で読み書きする例はChcpコマンドの例をご覧ください。

関連項目

• Dirコマンド - 単にファイルを列挙して表示したい場合に用います。
• 「%」文字 - 変数の展開方法の拡張版について説明しています。
• 括弧「( )」 - ファイル/トークンごとに複数のコマンドを実行する際にForとよく組み合わされます。
• Setlocalコマンド - 環境変数の遅延展開機能を有効化する際に用います。
• Findstrコマンド - 列挙対象をフィルターしたい場合にパイプ「|」とともに用います。
• 「^」文字 - Forに渡すコマンドにパイプや括弧を含めたいときに使います。
• Forfilesコマンド - Forと同様にファイルを列挙してコマンドを実行する際に用います。