Xcopy - DOS/Command Prompt Reference

Usage

Xcopy has the capability to copy files similar to Copy command, but it is more feature-rich than the Copy command. It supports copying multiple files, bulk copying of directories, and offers additional functionality beyond the Copy command. For example,

xcopy /S /E C:\Foo N:\Bar\

... by specifying options and providing the ‘source’ and ‘destination’ paths like the above, you can perform the copy operation using Xcopy (the options can be appended at the end such as ‘C:\Foo N:\Bar\ /S /E’).

One of the features of Xcopy is the abundance of options for controlling copy operations compared to the Copy command. The representative option includes as follows:

• /Y : Force overwrite
• /S : Copy subdirectories (empty directories are not copied)
• /E : Copy subdirectories, including empty ones (also achievable with ‘/S /E’)
• /Q : Suppress screen output during copying

For more samples, please see ‘Samples’ section.

Syntax

xcopy[.exe] <source> [<destination>] [/A | /M] [/D[:<date>]] [/P]
  [/S] [/E] [/V] [/W] [/Y] [/-Y] [/C] [/I] [/Q] [/F] [/L] [/H] [/R]
  [/T] [/U] [/K] [/N] [/G] [/O] [/X] [/Z] [/B] [/J]
  [/EXCLUDE:<file1>[+<file2>]...]
  [/COMPRESS]

Details

Xcopy is a program for copying files and directories that allows for more detailed specifications than Copy command. Unlike Copy, Xcopy also allows copying files along with their directory structure.

[MS-DOS] Xcopy copies 0-byte files (Copy command cannot).

[Windows XP? or later] If you need to perform file selection based on file attributes, timestamp, or mirror the source and destination, consider using Robocopy.

Samples

Sample 1

xcopy /Y C:\Documents\hoge.txt D:\Backup\

Copy the file ‘C:\Documents\hoge.txt’ into the directory ‘D:\Backup’. The ‘/Y’ option forces unconditional (forceful) overwrite if the file already exists.

Sample 2

xcopy /Y /Q /S /E E:\My\Directory\*.* F:\Foo\Bar\Directory\

Copy the entire contents (files and subdirectories) of the directory ‘E:\My\Directory’ to the directory ‘F:\Foo\Bar\Directory’. With the ‘/S /E’ options, the directory structure is also copied. (The ‘/Y’ option allows unconditional overwrite if some files already exist inside.) Additionally, the ‘/Q’ option suppresses the display of file names during the copy process.

* If ‘F:\Foo\Bar\Directory’ does not exist, it will be automatically created.

Sample 3

xcopy /A /S /E /Y C:\MyDoc\*.* D:\Backup\MyDoc\

Copy all files within ‘C:\MyDoc’ that have the ‘Archive attribute’ to the ‘D:\Backup\MyDoc’ directory. During this process, also copy files located within subdirectories of ‘C:\MyDoc’ (maintaining the same directory structure).

* Please see also samples of Attrib command.

Sample 4

xcopy /Y /Q /S /E /M E:\My\Directory\*.* F:\Foo\Bar\

Copy all files and subdirectories within the directory ‘E:\My\Directory’ that have the ‘Archive attribute’ to the directory ‘F:\Foo\Bar’ (forcefully overwriting if some files already exist inside). The ‘/M’ option is present, so the ‘Archive attribute’ on the source files is removed during the copy process.

Sample 5

echo F| xcopy /M file1.txt file2.txt

If ‘file1.txt’ has the ‘Archive attribute’, copies ‘file1.txt’ and creates ‘file2.txt’. Because ‘file2.txt’ does not end with ‘\’, the prompt ‘Does file2.txt specify a file name or directory name on the target (F = file, D = directory)?’ is displayed, but to automatically input ‘F’, Echo command is used.

Note that after executing the command, the ‘Archive attribute’ of ‘file1.txt’ is removed (while the ‘Archive attribute’ of ‘file2.txt’ remains).

* When copying individual files, the usual practice is to use the Copy command.
* If ‘echo D’ is used instead of ‘echo F’, Xcopy creates a directory named ‘file2.txt’ and copies ‘file1.txt’ into that directory.
* If file2.txt exists, the prompt ‘Overwrite file2.txt (Yes/No/All)?’ instead of ‘Does file2.txt specify a file name or directory name on the target (F = file, D = directory)?’ is displayed (while the given input is only ‘F’), causing the above command fails. To force overwrite, /Y option must be used.

Sample 6

xcopy /U /S /E /Y Z:\Data\*.* E:\Current\Data\

[Windows 95 or later] Copy all files from ‘Z:\Data’ to ‘E:\Current\Data’, but do not copy if the file to be copied already exists in the destination and the destination file is newer. This is useful for situations where you only want to copy files when there are updates.

Sample 7 (Batch file)

@echo off
setlocal enableextension
for /F "tokens=1,2,* delims=:" %%i in ("%TIME%") do set MYTIME=%%i%%j
set DIR_NAME=E:\Backup\src_%DATE:/=%_%MYTIME%
if not exist "%DIR_NAME%" md "%DIR_NAME%"
xcopy /S /E /Y /Q /EXCLUDE:"E:\Backup\excludes.txt" D:\Develop\src\*.* "%DIR_NAME%\"

[Windows NT series] [Extensions] Creates a directory in ‘E:\Backup’ with the date and time in its name, and within that directory, copies all files from ‘D:\Develop\src’, excluding those that match the patterns listed in ‘E:\Backup\excludes.txt’. Creating a batch file with such descriptions allows for the easy creation of backups at that particular point in time.

Note that characters like ‘/’ and ‘:’ cannot be used in filenames, so For and Set are used to remove these characters from the date and time.

See also

• Copy command - used to simply copy files.
• Robocopy command - used to copy files with more complex conditions.
• Rmdir(Rd) command - used to delete a directory.
• Deltree command - used to delete a directory in MS-DOS and Windows95/98/Me.
• Attrib command - the Archive attribute can be checked/changed by using Attrib command.
• Wildcards (* and ?) - Xcopy command accepts wildcards.