Using environment variables - DOS/Command Prompt Reference

About environment variables

Environment variables are variables that exist within the space (environment) where various programs operate, hence the name ‘environment’. An environment variable is composed of a pair of a ‘name’ and a ‘value’, and there are multiple environment variables within the environment.

Environments are generally created independently for each program executed. Additionally, typically, when one program executes another program, the environment is duplicated, and the executed program belongs to this new environment. Therefore, even if you change the value of an environment variable within a program, those changes will be discarded once the program is terminated. For example, if you change an environment variable within the command prompt, that change will only affect the command prompt and the programs executed from there. When you exit using a command like Exit, the changes will be reverted as if they never occurred.

Depending on the command or program being executed, there are cases where specific environment variables are read, and their values are utilized to determine the behavior of the program. As an example, the Copy command reads an environment variable called ‘COPYCMD’ and processes its value as arguments for the command. Therefore, in batch programs, it is possible to describe the process of ‘setting the value of specific environment variables and then launching a specific program’ (some batch programs are created with this purpose).

Using environment variables

Environment variables can be used by enclosing the variable name with percent signs (%) as follows:

echo %MYVAR%
%SystemRoot%\system32\notepad.exe hoge.txt

Additionally, when setting a value for a variable, the Set command is used.

set MyVar=Hello

The variable name retains the capitalization used when initially set, but the capitalization is not distinguished and is used and managed without case sensitivity.

Please noted that when using ‘%’ to incorporate the value of an environment variable, the value of the environment variable is expanded before executing the command. Please see the examples below for more details.

[Windows NT series] By using Setlocal and Endlocal, it is possible to temporarily duplicate the ‘environment’ and execute commands within that environment. However, during this period, please note that the environment variables in the original environment cannot be modified (they will be discarded at the end of Endlocal or program execution).

[Windows NT series] [Extensions] When using the ‘enabledelayedexpansion’ option with Setlocal, it becomes possible to use ‘!’ instead of ‘%’ for variable expansion. This is used when you want to delay the timing of expanding environment variables, not at the execution time of the entire block of commands, but at the timing of executing each command within the block. For specific details, please refer to the examples mentioned later and the page ‘!’.

Commonly used variables

[Windows NT series] [Extensions] For information about special environment variables provided by Command Prompt, please refer to the ‘%’ page.

Notices

The timing of environment variable expansion is generally before the execution of the command. Therefore, depending on the contents of the environment variables, it may not be possible to execute the command correctly. For example,

if not %OS%==Windows_NT goto NotSupported

... this is executed as follows when the value of ‘OS’ does not exist.

if not ==Windows_NT goto NotSupported

This syntax is invalid in MS-DOS and Windows 95/98/Me.

To avoid invalidity,

if not "%OS%"=="Windows_NT" goto NotSupported

... this is expanded as follows:

if not ""=="Windows_NT" goto NotSupported

... becoming executable in MS-DOS and Windows 95/98/Me as well.

[Windows NT series] In Windows NT-based systems (Command Prompt), the use of Set increases the characters that can be set in environment variables, so it is important to pay even more attention to the values of environment variables. For example,

set MYVAR1=^<hoge^>

... executing this sets the value ‘<hoge>’ into ‘MYVAR1’, so

echo %MYVAR1%

... this command line will be expanded to:

echo <hoge>

... and it is interpreted as a command containing redirection ‘<’ and ‘>’.

Samples

Sample 1

%COMSPEC% /k myprog1.bat

Assuming that the program/command is stored in the environment variable ‘COMSPEC’, this executes the program/command with the argument ‘/k myprog1.bat’.

Note that COMSPEC usually specifies the path to Command.com (MS-DOS, Windows 95/98/Me) or Cmd.exe (Windows NT series). For information about the ‘/k’ option, please refer to the respective pages.

Sample 2 (Batch file)

set TEMP_FILE=%TEMP%\tempdata.txt
echo AppVersion: %HOGE_VERSION%>"%TEMP_FILE%"
echo Language: %HOGE_LANGUAGE%>>"%TEMP_FILE%"
piyo.exe "%TEMP_FILE%"
del "%TEMP_FILE%"

Assuming that the environment variable ‘TEMP’ contains a directory, this sets the path pointing to the file ‘tempdata.txt’ within that directory as ‘TEMP_FILE’. Then, using the Echo command, ‘>’, and ‘>>’, this writes data to that file. Afterward, this specifies the file's path (the content of ‘TEMP_FILE’) as an argument for ‘piyo.exe’, executes it, and finally deletes the file.

Sample 3

set INPUT_DIR=.\Files
set OUTPUT_DIR=.\Output
trans.exe

Sets the environment variables ‘INPUT_DIR’ and ‘OUTPUT_DIR’ and executes ‘trans.exe’. Since ‘trans.exe’ is executed within a new environment copied from the current environment, the values set for these environment variables here can be used within ‘trans.exe’. Therefore, by pre-setting the environment variables that the program uses, you can control the behavior of the program.

Sample 4

set /p MY_OPTION="Enter the option:"
foo.exe /option:"%MY_OPTION%"

[Windows NT series] [Extensions] Uses the Set command to prompt for arbitrary input for the value of the environment variable ‘MY_OPTION’ and passes that value as an argument to ‘foo.exe’. To prevent unintended behavior, the value of ‘MY_OPTION’ is enclosed in double quotes (" "). (Note: In this case, ‘foo.exe’ needs to correctly interpret the double quotes and their contents.)

Sample 5 (Batch file)

setlocal enabledelayedexpansion
nmake || exit /b !errorlevel!
bar

[Windows NT series] [Extensions] Enables the use of ‘!’ with Setlocal and then executes ‘nmake’ command. If ‘nmake’ command fails (returns a non-zero exit code), the batch file is terminated using the Exit command (see also "||"). In this code, when using exit codes,

nmake || exit /b %errorlevel%

... using ‘%errorlevel%’ like the above treats the commands connected by ‘||’ as a single ‘block’. Therefore, before executing ‘nmake’, all the environment variables included in this ‘block’ are expanded, and the code will be as following:

nmake || exit /b 0

... resulting it will not be able to return the correct exit code if ‘nmake’ fails.